MetaTrader/MQL: チャート上に矩形を描画する (OBJ_RECTANGLE, CChartObjectRectangle)

bool ObjectCreate(
   long chart_id,     // チャート識別子（0 はカレントチャート）
   string name,       // オブジェクト名 (ラベルの識別子）
   ENUM_OBJECT type,  // オブジェクトの型（OBJ_LABEL を指定）
   int sub_window,    // ウィンドウインデックス（0 はメインウィンドウ）
   datetime time1,    // 1 番目のアンカーポイントの時間（ラベルの場合は使用しない）
   double price1,     // 1 番目のアンカーポイントの価格（ラベルの場合は使用しない）
   // ...残りは省略可...
)

if (!::ObjectCreate(0, "Rect1", OBJ_RECTANGLE_LABEL, 0, 0, 0)) {
    // 矩形ラベルオブジェクトの作成に失敗
}

#property copyright "maku"
#property link      "https://toushi.maku.blog/"
#property version   "1.00"
#property strict
#property indicator_chart_window

#include <stdlib.mqh>  // ErrorDescription

static const string RECT_NAME = "Rect1";  // 描画オブジェクトの ID

bool AddRect() {
    const int chart = 0;            // 0 means the current chart
    const int subWindow = 0;        // 0 means the main window
    const string name = RECT_NAME;  // Object ID to be added

    // Create a new rectangle
    if (!::ObjectCreate(chart, name, OBJ_RECTANGLE_LABEL, subWindow, 0, 0)) {
        ::Alert("Failed to create a rect: ", ErrorDescription(::GetLastError()));
        return false;
    }

    // Position
    ::ObjectSetInteger(chart, name, OBJPROP_CORNER, CORNER_LEFT_UPPER);
    ::ObjectSetInteger(chart, name, OBJPROP_XDISTANCE, 30);
    ::ObjectSetInteger(chart, name, OBJPROP_YDISTANCE, 30);
    ::ObjectSetInteger(chart, name, OBJPROP_XSIZE, 100);
    ::ObjectSetInteger(chart, name, OBJPROP_YSIZE, 50);

    // Background
    ::ObjectSetInteger(chart, name, OBJPROP_BGCOLOR, clrBlue);
    ::ObjectSetInteger(chart, name, OBJPROP_BACK, true);

    // Border
    ::ObjectSetInteger(chart, name, OBJPROP_BORDER_TYPE, BORDER_FLAT);
    ::ObjectSetInteger(chart, name, OBJPROP_COLOR, clrYellow);
    ::ObjectSetInteger(chart, name, OBJPROP_STYLE, STYLE_DOT);
    ::ObjectSetInteger(chart, name, OBJPROP_WIDTH, 1);

    // Drag and drop
    ::ObjectSetInteger(chart, name, OBJPROP_SELECTABLE, false);
    ::ObjectSetInteger(chart, name, OBJPROP_SELECTED, false);

    return true;
}

void DeleteRect() {
    const int chart = 0;  // 0 means the current chart
    ObjectDelete(chart, RECT_NAME);
}

//--- event handlers ---

int OnInit() {
    return AddRect() ? INIT_SUCCEEDED : INIT_FAILED;
}

void OnDeinit(const int reason) {
    DeleteRect();
}

int OnCalculate(const int rates_total, const int prev_calculated,
                const int begin, const double& price[]) {
    // Nothing to do
    return rates_total;
}

#include <stdlib.mqh>  // ErrorDescription
#include <ChartObjects/ChartObjectsTxtControls.mqh>  // CChartObjectRectLabel

// ここでは描画オブジェクトをグローバルに定義（終了時の自動削除のため）
CChartObjectRectLabel gRect;

bool AddRect() {
    const int chart = 0;      // 0 means the current chart
    const int subWindow = 0;  // 0 means the main window

    // Create a new rectangle
    if (!gRect.Create(chart, "Rect1", subWindow, 30, 30, 100, 50)) {
        ::Alert("Failed to create a rect: ", ErrorDescription(::GetLastError()));
        return false;
    }

    // Position
    gRect.Corner(CORNER_LEFT_UPPER);
    // gRect.X_Distance(30);
    // gRect.Y_Distance(30);
    // gRect.X_Size(100);
    // gRect.Y_Size(50);

    // Background
    gRect.BackColor(clrBlue);
    gRect.Background(true);

    // Border
    gRect.BorderType(BORDER_FLAT);
    gRect.Color(clrYellow); // Flat border color
    gRect.Style(STYLE_DOT);
    gRect.Width(1);

    // Drag and drop
    gRect.Selectable(false);
    gRect.Selected(false);

    return true;
}

//--- event handlers ---

int OnInit() {
    return AddRect() ? INIT_SUCCEEDED : INIT_FAILED;
}

void OnDeinit(const int reason) {
    // CChartObject will be automatically deleted by its destructor
}

int OnCalculate(const int rates_total, const int prev_calculated,
                const int begin, const double& price[]) {
    // Nothing to do
    return rates_total;
}