MetaTrader/MQL: CTrade クラスで注文を出す (MT5)

#include <Trade/Trade.mqh>

CTrade trade;  // CTrade インスタンスの生成

#include <Trade/Trade.mqh>  // CTrade
const double LOT = 0.1;  // 取引するロット数（ボリューム） 0.1 = 1万通貨

/** スクリプトのエントリポイント */
void OnStart() {
    CTrade trade;
    trade.SetDeviationInPoints(5);  // 許容するスリッページ（ポイント数）を設定
    if (!trade.Buy(LOT)) {  // 現在のチャートの通貨を、現在の買値 (Ask) で購入
        printTradeError(trade);
    }
}

/** トレード関数がエラーになったときのエラー出力 */
void printTradeError(const CTrade& trade) {
    uint code = trade.ResultRetcode();
    string desc = trade.ResultRetcodeDescription();
    printf("ERROR(%u): %s", code, desc);
}

bool Buy(
  double       volume,       // ポジションボリューム（0.1 = 1 万通貨）
  const string symbol=NULL,  // シンボル（NULL なら現在のシンボル）
  double       price=0.0,    // 価格（0 なら現在の買値 (Ask)）
  double       sl=0.0,       // 決済逆指値（同時に損切りの逆指値注文を出す）
  double       tp=0.0,       // 決済指値（同時に利食いの指値注文を出す）
  const string comment=""    // コメント
)

#include <Trade/Trade.mqh>

void OnStart() {
    CTrade trade;

    // 許容するスリッページ（ポイント数）を設定
    trade.SetDeviationInPoints(5);

    // 損切り価格、利食い価格を指定して成行の買い注文
    string sym = _Symbol;  // カレントチャートの通貨
    double lot = 0.1;  // ロット数
    double ask = SymbolInfoDouble(sym, SYMBOL_ASK);  // 現在の買値
    double sl = ask - pointToPrice(sym, 100);  // 損切りは 100 ポイント下
    double tp = ask + pointToPrice(sym, 200);  // 利食いは 200 ポイント上

    if (!trade.Buy(lot, sym, ask, sl, tp)) {
        printTradeError(trade);
    }
}

// 指定した通貨において、ポイント数を価格に変換します。
double pointToPrice(string symbol, uint point) {
    double rate = SymbolInfoDouble(symbol, SYMBOL_POINT);
    return rate * point;
}

#property strict
#include <Trade/Trade.mqh>  // CTrade

input double Lot = 0.1;  // 取引するロット数（ボリューム）
input ulong Slippage = 3;  // 最大許容スリッページポイント
// Auto-generated by https://toushi.maku.blog/p/p6fgxgf/
input ulong Magic = 58146000;  // EA のマジックナンバー

class MyAlgo {
    CTrade m_trade;
    bool m_isOrdered;  // 一度だけオーダーするためのフラグ

public:
    void Init() {
        m_isOrdered = false;
        m_trade.SetDeviationInPoints(Slippage);  // 最大許容スリッページポイント
        m_trade.SetExpertMagicNumber(Magic);  // EA のマジックナンバーを設定
    }

    /** 最初の呼び出し時のみ、成行買いを行います。 */
    void BuyOnce() {
        if (m_isOrdered) return;
        m_isOrdered = true;

        // 現在のチャートの通貨を、現在の買値 (Ask) で購入
        if (!m_trade.Buy(Lot)) printTradeError(m_trade);
    }

private:
    /** トレード関数がエラーになったときのエラー出力 */
    void printTradeError(const CTrade& trade) {
        uint code = trade.ResultRetcode();
        string desc = trade.ResultRetcodeDescription();
        printf("ERROR(%u): %s", code, desc);
    }
};

MyAlgo g_algo;

int OnInit() {
    g_algo.Init();
    return INIT_SUCCEEDED;
}

void OnTick() {
    g_algo.BuyOnce();
}